COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	BEGIN
C00005 ENDMK
C⊗;
BEGIN
FRAME bpark1; bpark1←FRAME(ROT(YHAT,3.14159),VECTOR(15,45,0));
BARM←bpark1;(AS BHAND 0); { initial condition }

FRAME base; base←FRAME(ROT(ZHAT,-3.142139),VECTOR(10.8,48.7, .129));
FRAME pallet_spot;(AS pallet_spot (TTMUL base TRANS(NILROTN,VECTOR(0.992,0.982,0))));
FRAME carb_spot;(AS carb_spot (TTMUL base (TMAKE NILROTN (VMAKE 7.94 2.06 0))));

FRAME pallet,pallet_grasp,pallet_place;
AFFIX pallet_grasp TO pallet 
	AT TRANS(ROT(XHAT,3.14159),VECTOR(1.32,1.08,0.5)) RIGIDLY;
AFFIX pallet_place TO pallet 
	AT TRANS(ROT(XHAT,3.14159),VECTOR(1.32,1.08,0.75)) RIGIDLY;
pallet←pallet_spot;

FRAME carb,carb_grasp;
AFFIX carb_grasp TO carb
	AT TRANS(ROT(XHAT,3.14159),VECTOR(0.09,-0.20,1.0)) RIGIDLY;
carb←carb_spot;

{ grasp the carburator }
OPEN BHAND TO 3.75;
MOVE BARM TO carb_grasp;
CENTER BARM;
AFFIX carb TO BARM;

{ place the carburator on the pallet }
MOVE carb TO pallet_place
	(DURATION > 2.0)
	 VIA pallet_place+VECTOR(0,0,4);
OPEN BHAND TO 3.75;
UNFIX carb FROM BARM;
AFFIX carb TO pallet;

{move the pallet & carb together }
MOVE BARM TO pallet_grasp;
CENTER BARM;
AFFIX pallet TO BARM;
MOVE pallet TO carb_spot
	(DURATION > 2.0)
	VIA pallet+VECTOR(0,0,4);
OPEN BHAND TO 3.75;
UNFIX carb FROM BARM;

{move the carburator}
OPEN BHAND TO 3.75;
MOVE BARM TO carb_grasp;
CENTER BARM;
AFFIX carb TO BARM;
MOVE carb TO pallet_spot
	VIA carb+VECTOR(0,0,4);

{let go}
OPEN BHAND TO 3.75;
UNFIX carb FROM BARM;
MOVE BARM TO bpark1;

END;